关于gom引擎个人商店摆摊触发各种问题详解,假人自动摆摊设置

gom引擎个人商店和人物白塔该触发是引擎默认的个人商店摆摊触发，不是仿古老摆摊触发。仿古老摆摊相关触发基本兼容古老,可以查看兼容古老部分，假人摆摊写点大点省的看不到了 ISDUMMY下面给大家详细讲解

前往开始摆摊或停止摆摊将触发 QFunction-0 [@ShopStall] 地图参数 ALLOWUSEMYSHOP 允许摆摊(必需先设置摆摊限制在指定地图才会生效)

[@ShopStall]
#IF
INSAFEZONE
;检测在安泉区
#ELSEACT
MESSAGEBOX 需要在安泉区才能摆摊
BREAK

#IF
CHECKSHOPSTALLSTATUS
;检测是不是在摆摊
#ACT
MESSAGEBOX 你是否确认要停止摆摊 @停止摆摊
#ELSEACT
MESSAGEBOX 你是否确认要开始摆摊 @确定开始

[@确定开始]
#if
ISDUPMODE
#say
请找一个空位置，不能与别人站在一起。
#ACT
BREAK

#if
#ACT
SHOPSTALL
;使用SHOPSTALL命令，如果正在摆摊就会停止摆摊，如果没有摆摊就会开始摆摊

[@停止摆摊]
#if
#ACT
SHOPSTALL
;使用SHOPSTALL命令，如果正在摆摊就会停止摆摊，如果没有摆摊就会开始摆摊

============================================================================================================

前往我的商店，如果还没有创建将触发[@QueryMyShopFail]

[@QueryMyShopFail]
#ACT
MESSAGEBOX 你还没有个人商店，是否创建你的个人商店？\\前往确定创建个人商店。 @创建个人商店 @取消

[@创建个人商店]
亲爱的玩家你好。这里可以申请开店。\
你可以把你的物品放到你的店铺里出售，\
游戏中的玩家可以查询到你要出售的物品。\
也可以把不用的物品放到店铺的仓库里。\
前往客户端中“店”就可以进入到你的店铺中,\
也可以查询其他用户的店铺和物品，\
可以很方便的把仓库物品和出售的物品相互转移。\
还可以进行摆摊操作。\

<我要开店(前往输入你喜欢的店铺名称)/@@InputString1>\

[@InputString1]
#IF
CHECKMYSHOP
#ACT
MESSAGEBOX 你已经有店铺了
BREAK

#IF
CHECKSHOPNAME <$STR(S1)>
#ACT
MESSAGEBOX <$STR(S1)>店铺名称已经存在，请重新选择一个
BREAK

#IF
#ACT
CREATEMYSHOP <$STR(S1)>

[@CreateMyShopOK]
#SAY
你的店铺创建成功

[@CreateMyShopFail]
#SAY
你的店铺创建失败

============================================================================================================

常量:
当前卖家名字 <$USERSHOPSELLER>
当前买家名字 <$USERSHOPBUYER>
当前购买或出售的物品常量和以前通用 <$CURRTEMNAME> <$G_CURRTEMNAME> <$CURRTEMINDEX> <$CURRTEMMAKEINDEX>
当前购买或出售的物品使用的货币类型名称 <$BUYITEMMONEYTYPENAME>
当前购买或出售的物品使用的货币类型值 <$BUYITEMMONEYTYPE>
当前购买或出售的物品的价格 <$BUYITEPRICE>

;上架触发 QF脚本触发
[@ConfirmShopItemUp]
#IF
#ACT
;ConfirmShopItemUp (0=允许上架 1=禁止上架)
ConfirmShopItemUp 1
sendmsg 6 商铺名称:<$USERSHOPSELLER>上架物品:<$G_CURRTEMNAME>,ID:<$CURRTEMINDEX>,货币名称:<$BUYITEMMONEYTYPENAME>,货币类型:<$BUYITEMMONEYTYPE>,物品价格:<$BUYITEPRICE>

;下架触发 QF脚本触发
[@ConfirmShopItemDown]
#IF
#ACT
;ConfirmShopItemDown (0=允许下架 1=禁止下架)
ConfirmShopItemDown 1
sendmsg 6 商铺名称:<$USERSHOPSELLER>下架物品:<$G_CURRTEMNAME>,ID:<$CURRTEMINDEX>,货币名称:<$BUYITEMMONEYTYPENAME>,货币类型:<$BUYITEMMONEYTYPE>,物品价格:<$BUYITEPRICE>

;购买触发买家触发 QF脚本触发
[@BuyUserShopItem]
#IF
#ACT
sendmsg 6 你购买了<$USERSHOPSELLER>出售的摆摊物品<$G_CURRTEMNAME>,ID:<$CURRTEMINDEX>,货币名称:<$BUYITEMMONEYTYPENAME>,货币类型:<$BUYITEMMONEYTYPE>,物品价格:<$BUYITEPRICE>

;个人商店取款触发 QF脚本触发
[@GetUserShopItemMoney]

注意：以下功能是仿古老摆摊功能。如果你使用的是个人商店，请查看个人商店部分

打开摆摊窗口之前首先执行Q-Function中的@StartMyShop脚本段.

脚本命令ForbidMyShop用于中断摆摊.

例子:以下脚本放在Q-Function中.

[@StartMyShop]
#if
ISDUPMODE
#say
请找一个空位置，不能与别人站在一起。
#ACT
ForbidMyShop
BREAK

#IF
NOT INSAFEZONE
#SAY
需要在安泉区使用摆摊功能！
#ACT
ForbidMyShop
BREAK

#IF
NOT IsOnMap 3
#SAY
需要在盟重使用摆摊功能.
#ACT
ForbidMyShop
BREAK

#IF
CheckLevelEx < 40
#SAY
需要40级才可以使用摆摊功能！
#ACT
ForbidMyShop

假人摆摊写点大点省的看不到了

[@假人上线自动摆摊]
#IF
ISDUMMY
#ELSEACT
BREAK
;检测是否已经创建过个人商店
#IF
CHECKMYSHOP
#ACT
;停止辅机
DUMMYSTOP
;开始摆摊
SHOPSTALL
#ELSEACT
;如果没有个人商店开始用自己的名字做为商店的名字创建个人商店
CREATEMYSHOP <$USERNAME>
;停止辅机
DUMMYSTOP
;开始摆摊
SHOPSTALL

相关推荐